עמוד ראשי מירק סקריפטינג סניפטים סריקת קלונים בערוץ

סריקת קלונים בערוץ

mIRC Snippets - בפורום זה יפורסמו קודים שימושיים למירק. לפרסום קודים יש לפרסמם תחילה בפורום "פרסום קודים ומדריכים" ולאחר מכאן הם יועברו לפורום זה.

הצטרף: 17 יולי 2010, 16:07
הודעות: 51
פורסם: 17 יולי 2010, 18:22
שם הקוד: סריקת קלונים בערוץ
יוצר: לא ידוע, אם מישהו מעוניין לקחת קרדיט על הקוד אני אשמח לשנות...
תיאור: קוד מעולה אשר מבצע סריקה של קלונים (כמה חיבורים עם אותו אייפי/משתמש Q)
הפעלה: שמים ברימוט (Alt+R) בדף חדש ולוחצים מקש ימיני בערוץ ו Clones Scan

menu channel {
  Clones Scan: { /clones $active }
}

alias clones {
  set -u10 %clonescheck $1
  var %1 = @Clones- $+ $1

  if ($1 == $null) { linesep -s | echo -s * Use: /clones <#channel> | linesep -s | halt }
  if ($me !ison $1) { linesep -s | echo -s * You're not on $1 | linesep -s | halt }
  if ($hget(%1) != $null) { hfree %1 }
  window -dC +l %1 -1 -1 550 200 tahoma 10 | clear %1
  aline %1 * Searching for clones on $+(,$1,,...)
  aline %1 * Progress: $+([,$str($chr(160),100),]) - 0%
  set %clones.prog 0 | set %clones.cid $cid
  hmake -m %1 20 | .enable #clones | .who $1
}
#clones off
raw 352:*:{
  var %1 = @Clones- $+ $2
  if ($window(%1) != $null) {
    scid %clones.cid | inc %clones.prog
    var %2 = $int($calc(%clones.prog * 100 / $nick($2,0)))
    rline %1 2 * Progress: $+([,,$str($chr(160),%2),,$str($chr(160),$calc(100 - %2)),]) - %2 $+ %
    hadd -m %1 $4 $addtok($hget(%1,$4),$6,32)
  }
  halt
}
raw 315:*:{
  var %1 = @Clones- $+ %clonescheck
  if ($window(%1) != $null) {
    aline %1 * Search is complete:
    var %2 = 0,%5,%6
    while (%2 < $hget(%1,0).item) {
      inc %2 | var %3 = $hget(%1,%2).item,%4 = $hget(%1,%3)
      if ($gettok(%4,0,32) > 1) {
        aline %1 - Found $ifmatch clones for $+(,*!*@,%3,:,) $replace(%4,$chr(32),$+(,$chr(44),,$chr(32)))
        var %5 = $true | inc %6 $ifmatch
      }
    }
    if (%5 == $null) { aline %1 - No clones were found. }
    else { aline %1 - Found total %6 clones. }
  }
  .timer 1 4 { unset %clones.* | .disable #clones }
  if ($hget(%1) != $null) { .timer 1 4 { hfree %1 } }
  halt
}
#clones end


תהנו!!

הצטרף: 29 יוני 2010, 16:13
הודעות: 111
פורסם: 18 יולי 2010, 17:45
יפה מאוד!

הצטרף: 01 יולי 2010, 07:43
הודעות: 368
פורסם: 18 יולי 2010, 23:09
אהבתי, הראשון שאני רואה עם דיאלוג מקצועי.
שימו לב: בוטי המשחק שאני בונה לא מתאימים לQuakenet אלא אם כן צויין אחרת.
<+vendetta-> סיאג לחוכמה שתיקה
<+vendetta--> בא לי מוח
<Ninja`> דפקתי נקנקיה

הצטרף: 01 יולי 2010, 07:18
הודעות: 95
פורסם: 21 יולי 2010, 07:44
כל הכבוד !
תמונה


חזור אל סניפטים

cron