QAuth Helper

[Ventox]

שם הקוד: QAuth Helper
יוצר: Ventox
גירסא: 1.0
תיאור: עוזר לנהל את ההתחברות לQAUTH
הפעלה: קליק ימני ו QAuth Helper
תמונה:

קוד: בחר הכל

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;; QAuth Dialog ;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

dialog QAuth {
  title "Q Auth Helper [/QAuth]"
  size -1 -1 107 96
  option dbu notheme
  check "Auto Auth On Connect to QuakeNet", 1, 5 50 100 10
  text "Auth name:", 2, 5 5 29 8
  edit "", 3, 36 5 69 10
  text "Auth pass:", 4, 5 16 29 8
  edit "", 5, 36 17 69 10, pass
  button "Auth me", 6, 77 28 28 12
  box "Settings", 8, 2 41 104 43
  check "Auto IP Hider (mode $me +x)", 9, 5 60 100 10
  button "IP Hider", 7, 49 28 28 12
  button "Reset", 10, 20 28 28 12
  edit "", 11, 2 85 103 10, read
  check "Remember me", 12, 5 71 100 10
}
on *:dialog:QAuth:init:*: {
  if (%QAuth.username) { did -a $dname 3 %QAuth.username }
  if (%QAuth.password) { did -a $dname 5 %QAuth.Password }
  if (%QAuth.AutoAuth == ON) { did -c $dname 1 }
  if (%QAuth.AutoIPHider == ON) { did -c $dname 9 }
  if (%QAuth.Rememberme == ON) { did -c $dname 12 }
  if (!%QAuth.username) || (!%QAuth.password) { did -b $dname 6 }
}
on *:CONNECT: {
  if ($network == QuakeNet) && (*.quakenet.org iswm $server) {
    if (%QAuth.AutoAuth == ON) && (%QAuth.Username) && (%QAuth.Password) { .msg Q@CServe.quakenet.org AUTH %QAuth.Username %QAuth.Password }
  }
}
on *:dialog:QAuth:edit:*: {
  if ($did == 3) {
    if (%QAuth.Rememberme == ON) { Set %QAuth.Username $did($dname,3) }
    if ($did($dname,5)) { did -e $dname 6 }
  }
  if ($did == 5) {
    if (%QAuth.Rememberme == ON) { Set %QAuth.Password $did($dname,5) }
    if ($did($dname,3)) { did -e $dname 6 }
  }
  if (!$did($dname,5)) || ($did($dname,3) == $null) { did -b $dname 6 }
}
on *:dialog:QAuth:sclick:*: {
  if ($did == 10) { unset %QAuth.Auto* | did -r $dname 3,5 | did -ra $dname 11 Settings restarted. }
  if ($did == 7) { mode $me +x | did -ra $dname 11 IP Hider is ON }
  if ($did == 6) { .msg Q@CServe.quakenet.org AUTH $did($dname,3) $did($dname,5) | Set %QAuth.Status ON | did -ra $dname 11 Sending AUTH Details... }
  if ($did == 1) { Set %QAuth.AutoAuth $iif(%QAuth.AutoAuth !== ON,ON,OFF) | did -ra $dname 11 Auto Auth: %QAuth.AutoAuth }
  if ($did == 9) { Set %QAuth.AutoIPHider $iif(%QAuth.AutoIPHider !== ON,ON,OFF) | did -ra $dname 11 Auto IP Hider is now: %QAuth.AutoIPHider }
  if ($did == 12) {
    Set %QAuth.Rememberme $iif(%QAuth.Rememberme !== ON,ON,OFF)
    if (%QAuth.Rememberme == ON) {
      if ($did($dname,3)) { Set %QAuth.Username $ifmatch }
      if ($did($dname,5)) { Set %QAuth.Password $ifmatch }
    }
    if (%QAuth.Rememberme == OFF) { unset %QAuth.Password | unset %QAuth.Username }
    did -ra $dname 11 Remember me is now: %QAuth.Rememberme
  }
}
alias QAuth { if (!$dialog(QAuth)) dialog -m QAuth QAuth }
on *:NOTICE:*:?: {
  if ($nick == Q) && (%QAuth.Status == ON) && ($dialog(QAuth)) && ($1- == Username or password incorrect.) { did -ra QAuth 11 Username or password incorrect. | unset %QAuth.Status }
  if ($nick == Q) && (%QAuth.Status == ON) && ($dialog(QAuth)) && (You are now logged in as* iswm $1-) { did -ra $dname 11 $1- | unset %QAuth.Status }
  if ($nick == Q) && (%QAuth.Status == ON) && ($dialog(QAuth)) && ($1- == AUTH is not available once you have authed.) { did -ra QAuth 11 You are already authed. | unset %QAuth.Status }
  if ($nick == Q) && (You are now logged in as* iswm $1-) { if (%QAuth.AutoIPHider == ON) mode $me +x }
}
menu * {
  QAuth Helper by Ventox { QAuth }
}


[Ohad]

קוד נחמד ביותר ואחלה עיצוב
כמה הערת קטנות:

• כדאי להצפין את הסיסמא בצורת הצפנה מסוימת, לא טוב שהפרטים שמורים ככה במשתנה
• ב-on connect בדקת רק אם הרשת מתאימה, אבל לא בדקת גם עם הסרבר מתאים מה שנותן מקום לפריצות למשתמשי Q, הייתי מציע לך לבדוק:
  
  קוד: בחר הכל

  if (*.quakenet.org iswm $server)

[uns]

עוזר מאוד למתחילים.

[XtrAp]

תודה.

[Disel]

Ohad כתב:

קוד נחמד ביותר ואחלה עיצוב
כמה הערת קטנות:

• כדאי להצפין את הסיסמא בצורת הצפנה מסוימת, לא טוב שהפרטים שמורים ככה במשתנה
• ב-on connect בדקת רק אם הרשת מתאימה, אבל לא בדקת גם עם הסרבר מתאים מה שנותן מקום לפריצות למשתמשי Q, הייתי מציע לך לבדוק:
  
  קוד: בחר הכל

  if (*.quakenet.org iswm $server)

[*] איך אתה מצפה שהוא יצפין תסיסמא? זה כולה התחברות פשוטה למשתמש קיו..
[*] איך בדיוק מישהו אמור לפרוץ למשתמשי קיו בדרך הזאת o.O

אבל בתחלס זה סקריפט שימושי לכאלה שמתחילם במירק או שמתבלבלים מזה וצריכים עזרה

[Ventox]

[*] הוא התכוון שכדאי שהסיסמא לא תישמר פשוט במשתנה.. שתישמר במקום אחר דיי סודי ושתהיה מוצפנת לפי הצפנה שלי.

[*] יש כאלה שמתחברים לסרברים אחרים שקוראים להם QuakeNet אבל הם לא באמת *.quakenet.org
ומן הסתם זה שולח אוטומטית את ההודעה לQ .. את הודעת ההתחברות.. אז כדאי לבדוק אם הסרבר שמתחברים אליו הוא באמת של Quakenet ולא Fake

[Disel]

אולי גם כדאי לך להוסיף אפשרות של יצירת משתמשי קיו, אני מכיר מלא ילדים שלא יודעים איך לעשות את זה ואז חופרים לאנשים בוונט..

[Nixxo]

תודה.. יעזורלהרבה אנשים...

[Xronic]

שהוא התכוון להצפין הכוונה היא

קוד: בחר הכל

 $encode $decode

[Ventox]

"כדאי להצפין את הסיסמא בצורת הצפנה מסוימת"
הוא לא הגדיר את צרות ההצפנה יש אין סוף צורות הצפנה
ולא כדאי להשתמש ב $encode $decode יש באגים לפעמים

[Ohad]

Ventox כתב:

"כדאי להצפין את הסיסמא בצורת הצפנה מסוימת"
הוא לא הגדיר את צרות ההצפנה יש אין סוף צורות הצפנה
ולא כדאי להשתמש ב $encode $decode יש באגים לפעמים

איזה באגים בדיוק יש?
הדבר היחידי שבעייתי ב-decode$ זה שהוא לא תמיד מאושר בהגדרות המירק.

[Ventox]

זה הבעיה שאני מדבר עליה.
בעיה מעצבנת שפתאום הוא נועל את עצמו לבד

[TrAsKy]

תן איזה

קוד: בחר הכל

if (!$decode(YQ==,m)) { noop $input(Error! You must enable Decode from Options>Other>Lock>Decode,ho,Error!) }

או שפשוט תעשה שאם (!$decode(YQ==,m)) זה יצפין עם chrים או שלא יצפין בכלל...

[Ohad]

TrAsKy כתב:

תן איזה

קוד: בחר הכל

if (!$decode(YQ==,m)) { noop $input(Error! You must enable Decode from Options>Other>Lock>Decode,ho,Error!) }

או שפשוט תעשה שאם (!$decode(YQ==,m)) זה יצפין עם chrים או שלא יצפין בכלל...

קוד: בחר הכל

$lock(decode)

?

[Ventox]

חח אוהד

בקיצור הבנתם את הרעיון... צריך לעשות הצפנה מיוחדת או CHARS או BINARY... קיצר אין לי כוח לזה כרגע