Badwords v1

[XtrAp]

שם הקוד: Badwords
יוצר: XtrAp
גירסא: v1
תיאור: הקוד מאפשר להעיף אנשים שמשתמשים במילים אסורות מהערוץ. את המילים אתם בוחרים.
הפעלה: מקש ימני -> Badwords System. שם אתם יכולים להוסיף מילים, לשנות ערוץ, לשנות את כמות האזהרות לפני באן, להפעיל ולכבות את הסקריפט. בשביל למחוק מילה אתם צריכים ללחוץ עליה פעמיים.
תמונה:

קוד: בחר הכל

on !*:text:*:%bad.ch:{
  if (%bad.status == on) && ($me isop #) && ($nick isreg #) {
    var %bad.x = 1
    while ($gettok(%bad.words,%bad.x,44)) {
      if ($v1 isin $1-) {
        var %bad.word $v1
        inc -u900 %bad. [ $+ [ $wildsite ] ]
        if (%bad. [ $+ [ $wildsite ] ] > %bad.max) ban -ku900 # $nick 2 Banned: Badword detected! ( $+ %bad.word $+ ) No more warning. 
        else { kick # $nick Badword detected! ( $+ %bad.word $+ ) Warning: $+($v1,/,%bad.max) }
        halt
      }
      else inc %bad.x
    }
  }
}
alias bd dialog $iif($dialog(badwords),-v,-m) BadWords BadWords
dialog BadWords {
  title "Bad Words"
  size -1 -1 71 158
  option dbu
  list 1, 4 8 63 91, size
  button "Turn ON", 3, 40 100 30 9
  box "Bad Words List", 2, 2 0 67 100
  edit "", 4, 1 100 38 10, disable
  button "Add Word", 5, 1 130 38 10
  button "Clear list", 6, 40 130 30 10
  edit "", 7, 1 110 38 10, disable
  button "Change", 9, 40 110 30 9
  edit "This Script made by XtrAp", 8, 1 140 68 10, disable
  link "www.mIRCs.co.il", 10, 13 150 42 8
  edit "", 11, 1 120 38 10, disable
  button "Change", 12, 40 120 30 9
}
on *:dialog:BadWords:*:*:{
  if ($devent == init) {
    if (%bad.words) {
      var %x = 1
      while ($gettok(%bad.words,%x,44)) {
        did -a $dname 1 $v1
        inc %x
      }
    }
    did -a $dname 4 Status: $iif(%bad.status == ON,ON,OFF)
    did -a $dname 7 Warnings: $iif(%bad.max,$v1,0)
    did -ra $dname 3 Turn $iif(%bad.status == ON,OFF,ON)
    did -a $dname 11 Ch: %bad.ch
  }
  elseif ($devent == dclick) && ($did == 1) {
    set %bad.words $remtok(%bad.words,$did(1).seltext,44)
    did -d $dname 1 $did(1).sel
  }
  elseif ($devent == sclick) {
    if ($did == 3) {
      set %bad.status $iif(%bad.status == ON,OFF,ON)
      did -ra $dname 4 Status: %bad.status
      did -ra $dname 3 Turn $iif(%bad.status == ON,OFF,ON)
    }
    elseif ($did == 9) {
      if ($input(Enter how many warnings before ban:,e,Bad Words Settings)) {
        did -ra $dname 7 Warnings: $v1
        set %bad.max $v1
      }
    }
    elseif ($did == 5) {
      if ($input(Insert the word that you want to block,e,Bad Words Settings)) {
        set %bad.words $addtok(%bad.words,$v1,44)
        did -a $dname 1 $v1
      }
    }
    elseif ($did == 6) {
      if ($input(Are you sure you want to clear the bad words list?,yq,Bad Words Settings)) {
        unset %bad.words
        did -r $dname 1
      }
    }
    elseif ($did == 12) {
      if ($input(Enter the channel pls,e,Bad Words Settings)) {
        did -ra $dname 11 Ch: $v1
        set %bad.ch $v1
      }
    }
    elseif ($did == 10) url -an www.mIRCs.co.il
  }
}
on *:load: bd
menu * {
  Badwords System: bd
}


[KaryoS]

תודה אחי

[Premium]

חחח דור חולה עליך אבל רק בגללי בניתה את זה חחחחח

[uns]

הרעיון והקוד יפים מאוד,
אך לדעתי אולי היה אפשר לרווח טיפה את איזור הכפתורים של הדיאלוג.

[ZxoR]

הגיון: כשאומרים פעם שלישית גלידה, מתי באה הגלידה? בפעם השלישית או בפעם שאחרי השלישית?
מעשי: אני הגדרתי שלאחר 3 פעמים שמקללים מקבלים באן, אבל אתה בקוד עשית שבפעם השלישית עוד מקבלים אזהרה, ובפעם הרביעית עפים.
3\3 = 100%, לא יכול להיות יותר, 100% קללות = באן.

לפי בקשתך: מי שחושב שאני צודק שצריך לעשות שכמות הקללות ככמות האזהרות שיגיב ויגיד (דור ביקש).

[XtrAp]

תראה פה התכוונתי לדבר כזה, אתה כותב כמה אזהרות הבן אדם מקבל לפני הבאן. זה כתוב גם בהסבר.....
ואז אם נגיד כתבת במספר האזהרות 3 אז אתה מקבל 3 אזהרות ואז רק אתה מקבל את הבאן.
כי תחשוב, לפי מה שאתה אומר.. אם אני כותב במספר האזהרות - 1 אז איך שהוא כותב משהו הוא ישר מקבל באן!

[ZxoR]

בסייפר נקודות לפני באן זה 5, כשאדם מקבל 5 נקודות הוא עף. ככה זה עובד גבר.