מציג מידע על אתרים - IP/Host information

[Editor]

שם הקוד: IP/Host information
יוצר: Doof
גרסה: 1.0
תיאור: מציג מידע על אתרים
הפעלה: כנסו למירק ולחצו במקלדת ALT + R, לחצו למעלה בצד שמאל File ואז New, תעתיקו את הסקריפט ותאשרו. לאחר מכן יש להשתמש בפקודה /ipinfo ואז כתובת האתר כדי להציג את המידע.

קוד: בחר הכל

:::::::::::::::::::::::::::::::::::::::
::::::::: IP/Host information :::::::::
::::::::::: Usage: /ipinfo ::::::::::::
::::::::::: Created By Doof :::::::::::
:::::::::::::::::::::::::::::::::::::::
 
dialog ipinfo {
  title "IP/Host information [/ipinfo]"
  size -1 -1 150 110
  option dbu
  list 1, 4 22 142 70, sort size hsbar vsbar
  edit "", 2, 60 5 62 10, multi return autohs autovs limit 50
  text "Enter IP/Host address:", 3, 4 6 55 8
  box "", 4, 2 17 146 77
  box "", 5, 2 0 146 17
  button "Search", 6, 124 5 22 10
  button "Ok", 7, 2 96 37 12, ok
  button "Cancel", 8, 40 96 37 12, cancel
}
on *:dialog:ipinfo:*:*:{
  if ($devent == sclick) {
    if ($did == 6) && ($did($dname,2).text) {
      did -ra $dname 1 Resolving IP/Host...
      resolveip $did($dname,2).text
    }
    elseif ($did == 6) && (!$did($dname,2).text) {
      did -ra $dname 1 Please enter IP/Host address.
    }
  }
}
#DNSip off
on *:DNS:{
  if ($dns(0).ip) {
    set %info.ip $dns(0).ip
    sockopen ipinfo whois.cyberabuse.org 43
    did -r ipinfo 1
  }
  else {
    did -ra ipinfo 1 Invalid IP/Host.
  }
  .disable #DNSip
}
#DNSip end
 
on *:sockopen:ipinfo: {
  if ($sockerr) {
    did -ra ipinfo 1 Unable to connect to IP/host lookup server.
    sockclose ipinfo
  }
  else {
    sockwrite -nt ipinfo %info.ip
    did -r ipinfo 1
  }
}
 
on *:sockread:ipinfo: {
  if ($sockerr == 0) {
    var %var
    sockread %var
    if ($regex(%var,/IP range|Network name|Infos|Country|Abuse E-mail|Source/)) { did -a ipinfo 1 %var }
  }
}
alias ipinfo { dialog -m ipinfo ipinfo }
alias resolveip {
  sockclose ipinfo
  if ($regex($1,/^(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})$/)) { 
    sockopen ipinfo whois.cyberabuse.org 43
    set %info.ip $1-
  }
  if (!$regex($1,/^(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})$/)) {
    .enable #DNSip
    .dns $1-
  }
}
menu * {
  IP/Host dialog: /ipinfo
}

יש למצוא גם: pastebin.php?mode=view&s=29