בוט שליטה בקיו - QBot Commands

[Editor]

שם הקוד: QBot Commands
יוצר: Tomer953
גרסה: 1.0
תיאור: בוט שליטה בקיו
הפעלה: כנסו למירק ולחצו במקלדת ALT + R, לחצו למעלה בצד שמאל File ואז New, תעתיקו את הסקריפט ותאשרו.

קוד: בחר הכל

;*************************************************************************************
;*************************************************************************************
;*********************************** QBot Commands *************************************
;*************************************************************************************
;*************************************************************************************
on *:load:{ echo 4 -a * Q-Commands addon was Successfully Loaded! | echo 4 -a * type: /qbot for start }
;//Qbot
alias Qbot dialog -m qbot qbot
dialog Qbot {
  title "Q Commands"
  size -1 -1 148 278
  option dbu
  edit "#Channel", 1, 7 8 36 10, autohs
  button "Refresh", 13, 44 8 37 9
  box "Help", 45, 10 198 130 51
  text "Q-Commands by Tomer953 (953Script)", 53, 7 256 137 13
  edit "Press on one of the Question mark \'?\' to get help about the command. Notice: on Chanflags and ChanLev, buttons are \'\'+x\'\' and \'\'-x\'\' - depents on user\chan currently modes", 46, 11 206 127 40, read multi
  tab "ChanLev", 97, 6 19 138 233
  box "", 12, 89 35 51 111, tab 97
  box "Chanlev List (Add \ Remove)", 11, 11 35 79 111, tab 97
  button "?", 8, 124 46 11 10, tab 97 flat
  button "?", 50, 124 57 11 10, tab 97 flat
  button "?", 51, 124 79 11 10, tab 97 flat
  button "?", 5, 124 90 11 10, tab 97 flat
  button "?", 49, 124 101 11 10, tab 97 flat
  button "?", 85, 124 112 11 10, tab 97 flat
  button "?", 48, 124 123 11 10, tab 97 flat
  button "?", 87, 124 68 11 10, tab 97 flat
  list 2, 14 44 74 99, tab 97 size
  check "&Topic", 110, 95 133 24 10, tab 97
  check "&Owner", 3, 95 122 29 10, tab 97
  check "&Master", 52, 95 111 28 10, tab 97
  check "&Op", 6, 95 100 21 10, tab 97
  check "&Voice", 10, 95 89 24 10, tab 97
  check "&Known", 9, 95 78 28 10, tab 97
  check "&Give", 86, 95 67 23 10, tab 97
  check "&Auto", 4, 95 56 24 10, tab 97
  check "&Ban", 7, 95 45 21 10, tab 97
  button "?", 102, 124 134 11 10, tab 97 flat
  box "", 100, 11 142 129 20, tab 97
  text "", 103, 14 146 124 14, tab 97
  box "Commands for Your own User", 41, 10 163 130 35, tab 97
  button "?", 91, 64 171 11 10, tab 97 flat
  button "Change email", 83, 12 171 51 10, tab 97
  button "Change Password", 44, 12 183 51 10, tab 97
  button "?", 90, 64 183 11 10, tab 97 flat
  button "?", 96, 127 171 11 10, tab 97 flat
  button "+j", 95, 115 171 11 10, tab 97
  button "+w", 93, 115 183 11 10, tab 97
  button "?", 94, 127 183 11 10, tab 97 flat
  button "?", 89, 102 183 11 10, tab 97 flat
  button "mode +x", 43, 76 183 25 10, tab 97
  button "Auth", 42, 76 171 25 10, tab 97
  button "?", 88, 102 171 11 10, tab 97 flat
  tab "ChanFlags", 98
  edit "", 70, 98 157 38 10, tab 98 read
  button "?", 65, 124 145 11 10, tab 98 flat
  button "?", 66, 124 134 11 10, tab 98 flat
  button "?", 67, 124 123 11 10, tab 98 flat
  button "?", 68, 124 112 11 10, tab 98 flat
  button "?", 69, 124 101 11 10, tab 98 flat
  box "Channel Flags (+\-)", 27, 70 35 70 144, tab 98
  button "?", 60, 124 46 11 10, tab 98 flat
  button "?", 61, 124 57 11 10, tab 98 flat
  button "?", 62, 124 68 11 10, tab 98 flat
  button "?", 63, 124 79 11 10, tab 98 flat
  button "?", 64, 124 90 11 10, tab 98 flat
  check "+t &Topic Save", 58, 75 89 45 10, tab 98
  check "+w &Welcome", 31, 75 78 45 10, tab 98
  check "+p &Protect", 30, 75 67 45 10, tab 98
  check "+f &Force Topic", 29, 75 56 45 10, tab 98
  check "+b &Bitch", 28, 75 45 45 10, tab 98
  check "+c &Auto Limit", 54, 75 100 45 10, tab 98
  check "+e &Enforce", 55, 75 111 45 10, tab 98
  check "+k &known only", 56, 75 122 45 10, tab 98
  check "+p &Protect", 57, 75 133 45 10, tab 98
  check "+v &Voice all", 59, 75 144 45 10, tab 98
  text "Flags:", 71, 76 158 21 8, tab 98
  button "Ban Timer", 37, 15 43 33 10, tab 98
  button "?", 26, 50 43 11 10, tab 98 flat
  button "Ops History", 38, 15 54 33 10, tab 98
  button "?", 72, 50 54 11 10, tab 98 flat
  button "?", 73, 50 65 11 10, tab 98 flat
  button "ChanStats", 35, 15 65 33 10, tab 98
  button "Clear Chan", 40, 15 76 33 10, tab 98
  button "?", 74, 50 76 11 10, tab 98 flat
  button "?", 75, 50 87 11 10, tab 98 flat
  button "Set Welcome", 39, 15 87 33 10, tab 98
  button "SeTopic", 36, 15 98 33 10, tab 98
  button "?", 76, 50 98 11 10, tab 98 flat
  button "?", 82, 50 109 11 10, tab 98 flat
  button "Recover", 33, 15 109 33 10, tab 98
  button "Deop All", 34, 15 120 33 10, tab 98
  button "?", 81, 50 120 11 10, tab 98 flat
  button "?", 80, 50 131 11 10, tab 98 flat
  button "Devoice All", 77, 15 131 33 10, tab 98
  button "Op", 23, 15 142 33 10, tab 98
  button "?", 79, 50 142 11 10, tab 98 flat
  button "?", 78, 50 153 11 10, tab 98 flat
  button "Voice", 24, 15 153 33 10, tab 98
  button "Invite me", 25, 15 165 33 10, tab 98
  button "?", 22, 50 165 11 10, tab 98 flat
  box "Channel Commands", 32, 11 35 55 144, tab 98
  tab "Bans", 99
  box "", 16, 12 110 127 28, tab 99
  box "Bans List", 14, 12 39 127 75, tab 99
  button "Delete All", 18, 14 126 39 10, tab 99
  button "Unban All", 20, 56 126 39 10, tab 99
  button "Add-Ban", 21, 97 115 39 10, tab 99
  button "Ban List", 47, 97 126 39 10, tab 99
  button "Unban Me", 19, 56 115 39 10, tab 99
  button "Delete", 17, 14 115 39 10, tab 99
  list 15, 14 47 122 64, tab 99 size
}
 
 
on *:dialog:qbot:init:0:{
  $iif($chr(35) isin $active,did -ra $dname 1 $active)
  .timeratr2 -m 0 300 did -ra qbot 53 $!atr(Q-Commands by tomer953 (www.953script.info))
}
on *:dialog:qbot:close:*:{ unset %qbot | .timeratr2 off }
on *:dialog:qbot:sclick:13:{ did -r qbot 2,15,70 | .enable #qchanlev | qrefresh all }
 
 
on *:dialog:qbot:sclick:2:{ 
  var %t $remove($gettok($did(qbot,2).seltext,2,32),+)
  did $iif(b isincs %t,-c,-u) qbot 7
  did $iif(a isincs %t,-c,-u) qbot 4
  did $iif(g isincs %t,-c,-u) qbot 86
  did $iif(k isincs %t,-c,-u) qbot 9
  did $iif(v isincs %t,-c,-u) qbot 10
  did $iif(o isincs %t,-c,-u) qbot 6
  did $iif(m isincs %t,-c,-u) qbot 52
  did $iif(n isincs %t,-c,-u) qbot 3
  did $iif(t isincs %t,-c,-u) qbot 110
}
 
alias q.chanflags.check {
  var %t $remove($did(qbot,70),+)
  did $iif(b isincs %t,-c,-u) qbot 28
  did $iif(f isincs %t,-c,-u) qbot 29
  did $iif(p isincs %t,-c,-u) qbot 30
  did $iif(w isincs %t,-c,-u) qbot 31
  did $iif(t isincs %t,-c,-u) qbot 58
  did $iif(c isincs %t,-c,-u) qbot 54
  did $iif(e isincs %t,-c,-u) qbot 55
  did $iif(k isincs %t,-c,-u) qbot 56
  did $iif(p isincs %t,-c,-u) qbot 57
  did $iif(v isincs %t,-c,-u) qbot 59
 
}
alias qrefresh {
  if ($1 == all) {
    .disable #snotice
    set %qbot 1
    .msg q chanlev $did(qbot,1)
    .timer -m 1 1500 .enable #qbanlist
    .timer -m 1 1500 .disable #snotice
    .timer -m 1 1500 set %qbot 1
    .timer -m 1 1500 .msg q banlist $did(qbot,1)
    .timer -m 1 2000 .enable #qchanflags
    .timer -m 1 2000 .disable #snotice
    .timer -m 1 2000 set %qbot 1
    .timer -m 1 3000 .msg q chanflags $did(qbot,1)
 
  }
  if ($1 == chanlev) {
    did -r qbot 2
    .msg q chanlev $did(qbot,1)
  }
  if ($1 == banlist) {
    did -r qbot 15
    .msg q banlist $did(qbot,1)
  }
  if ($1 == chanflags) {
    did -r qbot 70
    .msg q chanflags $did(qbot,1)
  }
}
 
#qchanlev on
on ^*:notice:*:?:{
  if ($nick == Q) {
    .disable #snotice
    set %qbot 1
    inc %a
    if (%a > 2) && (do this !isin $1-) && (Known Users !isin $1-) && (including the !isin $1-) && (Nothing changed !isin $1-) && (Removed registered !isin $1-) && (Username Flags !isin $1-) && (End Of !isin $1-) && (Total !isin $1-) did -a qbot 2 $1 $2
    if (*This command will give* iswm $1-) || (*including the ability* isin $1-) || (*type: GIVEOWNER* iswm $1-) echo 2 -a * _Q-Commands:_ $replace($1-,type:,type: /msg Q)
    if (Total isin $1) { .disable #qchanlev | did -ra qbot 103 $1- | unset %a | unset %qbot | .enable #snotice  }
  }
  halt
 
}
#qchanlev end
#qbanlist on
on ^*:notice:*:?:{
  if ($nick == Q) {
    .disable #snotice
    set %qbot 1
    if ($chr(35) isin $1)  did -a qbot 15 $1-2 
    if (End Of isin $1-) { .disable #qbanlist | unset %Qbot | .enable #snotice  }
  }
  halt
}
#qbanlist end
#qchanflags on
on ^*:notice:*:?:{
  if ($nick == Q) {
    .disable #snotice
    set %qbot 1
    if (Current channel flags isin $1-) {
      did -ra qbot 70 $6-
      q.chanflags.check
      .disable #qchanflags
      .enable #snotice
      unset %Qbot
    }
  }
  halt
}
#qchanflags end
 
 
;//chanlev options
on *:dialog:qbot:sclick:3:{ .enable #qchanlev  | .msg q $iif(n isincs $gettok($did(qbot,2).seltext,2,32),chanlev $did(qbot,1) $chr(35) $+ $gettok($did(qbot,2).seltext,1,32) -n,Giveowner $did(qbot,1) $chr(35) $+ $gettok($did(qbot,2).seltext,1,32))  | .qrefresh chanlev }
on *:dialog:qbot:sclick:7,4,86,9,10,6,52,110:{
  if ($gettok($did(qbot,2).seltext,1,32) != $null) {
    .enable #Qchanlev
    var %x
    if ($did == 7) set %x b
    if ($did == 4) set %x a
    if ($did == 86) set %x g
    if ($did == 9) set %x k
    if ($did == 10) set %x v
    if ($did == 6) set %x o
    if ($did == 52) set %x m
    if ($did == 110) set %x t
    .msg q chanlev $did(qbot,1) $chr(35) $+ $gettok($did(qbot,2).seltext,1,32) $iif(%x isincs $gettok($did(qbot,2).seltext,2,32),- $+ %x,+ $+ %x)
    .qrefresh chanlev
  }
  else echo 2 -a * Please Select a user from the list.
}
;//banlist options
on *:dialog:qbot:sclick:7:{ .enable #qbanlist | .msg q chanlev $did(qbot,1) $chr(35) $+ $gettok($did(qbot,2).seltext,1,32) +ab| .qrefresh banlist }
on *:dialog:qbot:sclick:17:{ .enable #qbanlist | .msg q bandel $did(qbot,1) $gettok($did(qbot,15).seltext,1,32) | .qrefresh banlist }
on *:dialog:qbot:sclick:18:{ .enable #qbanlist | .msg q banclear $did(qbot,1) | .qrefresh banlist }
on *:dialog:qbot:sclick:19:{ .enable #qbanlist | .msg q unbanme $did(qbot,1) | .qrefresh banlist }
on *:dialog:qbot:sclick:20:{ .enable #qbanlist | .msg q unbanall $did(qbot,1) | .qrefresh banlist }
on *:dialog:qbot:sclick:21:{ .enable #qbanlist | .msg q ban $did(qbot,1) $$?\"Enter Nick or hostmask To Ban" | .qrefresh banlist }
 
 
 
;/chanflags
on *:dialog:qbot:sclick:28:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(b isincs $did(qbot,70),-b,+b) }
on *:dialog:qbot:sclick:29:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(f isincs $did(qbot,70),-f,+f) }
on *:dialog:qbot:sclick:30:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(p isincs $did(qbot,70),-p,+p) }
on *:dialog:qbot:sclick:31:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(w isincs $did(qbot,70),-w,+w) }
on *:dialog:qbot:sclick:58:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(t isincs $did(qbot,70),-t,+t) }
on *:dialog:qbot:sclick:54:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(c isincs $did(qbot,70),-c,+c) }
on *:dialog:qbot:sclick:55:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(e isincs $did(qbot,70),-e,+e) }
on *:dialog:qbot:sclick:56:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(k isincs $did(qbot,70),-k,+k) }
on *:dialog:qbot:sclick:57:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(p isincs $did(qbot,70),-p,+p) }
on *:dialog:qbot:sclick:59:{ .enable #qchanflags | .msg q chanflags $did(qbot,1) $iif(v isincs $did(qbot,70),-v,+v) }
 
 
;//own commands
on *:dialog:qbot:sclick:42:{ var %x,%y | set %x $input(Username,e,Q-Commands,%auth.username) | set %y $input(Username,e,Q-Commands,%auth.password) | .msg q@cserve.quakenet.org auth %x %y | set %auth.username %x | set %auth.password %y }
on *:dialog:qbot:sclick:43:.mode $me +x
on *:dialog:qbot:sclick:44:.msg q@cserve.quakenet.org newpass $input(Enter Old Password,e,Auth Password,%auth.password) $$?\"Your New Password" $$?\"Your New Password Again"
on *:dialog:qbot:sclick:93:{ var %x,%y | set %x $input(Username,e,Q-Commands,%auth.username) | set %y $$?\"Enter + or -" |  if ($istok(-.+,%y,46) == $false) { echo 4 -a * _Error:_ Type +\- | halt } | .msg q chanlev $did(qbot,1) $+($chr(35),%x) %y $+ w | set %auth.username %x }
on *:dialog:qbot:sclick:95:{ var %x,%y | set %x $input(Username,e,Q-Commands,%auth.username) | set %y $$?\"Enter + or -" |  if ($istok(-.+,%y,46) == $false) { echo 4 -a * _Error:_ Type +\- | halt } | .msg q chanlev $did(qbot,1) $+($chr(35),%x) %y $+ j | set %auth.username %x }
on *:dialog:qbot:sclick:83:{ var %x,%y | set %x $input(Enter Password,e,Auth Password,%auth.password) | set %y $input(Enter New Mail,e,New Mail) | .msg Q@CServe.quakenet.org EMAIL %x %y %y }
 
;//channel commands
on *:dialog:qbot:sclick:37:.msg q BANTIMER $did(qbot,1) $$?\"enter Duration"
on *:dialog:qbot:sclick:38:.msg q CHANOPHISTORY $did(qbot,1)
on *:dialog:qbot:sclick:35:.msg q CHANSTAT $did(qbot,1)
on *:dialog:qbot:sclick:40:.msg q CLEARCHAN $did(qbot,1)
on *:dialog:qbot:sclick:39:.msg q welcome $did(qbot,1) $$?\"enter welcome messege"
on *:dialog:qbot:sclick:36:{ var %x | set %x $input(Set Topic,e,Set Topic,%q.topic) | .msg q settopic $did(qbot,1) %x | set %q.topic %x }
on *:dialog:qbot:sclick:33:.msg q recover $did(qbot,1)
on *:dialog:qbot:sclick:34:.msg q deopall $did(qbot,1)
on *:dialog:qbot:sclick:77:.msg q devoiceall $did(qbot,1)
on *:dialog:qbot:sclick:23:.msg q op $did(qbot,1)
on *:dialog:qbot:sclick:24:.msg q voice $did(qbot,1)
on *:dialog:qbot:sclick:25:.msg q invite $did(qbot,1)
 
;//Help Buttons
 
on *:dialog:qbot:sclick:60:did -ra $dname 46 +b BITCH Prevents users who don't have operator access on the channel from being opped (automatically deops them)
on *:dialog:qbot:sclick:61:did -ra $dname 46 +f FORCETOPIC Prevents channel ops from changing the topic. The SETTOPIC command must be used instead.
on *:dialog:qbot:sclick:62:did -ra $dname 46 +p PROTECT Any user with voice (+v) or operator (+o) access will have that status enforced on the channel at all times. Same effect as giving all ops and voices the +p chanlev flag.
on *:dialog:qbot:sclick:63:did -ra $dname 46 +w WELCOME Sends the welcome message to users joining the channel.
on *:dialog:qbot:sclick:64:did -ra $dname 46 +t TOPICSAVE Saves the topic when it changes. Such saved topics can be restored via settopic, or when the bot rejoins when a channel has been left empty.
on *:dialog:qbot:sclick:69:did -ra $dname 46 +c AUTOLIMIT Enables automatic limit feature - updates the channel limit at regular intervals to keep a certain number of free spaces. This can mitigate the effect of join floods.
on *:dialog:qbot:sclick:68:did -ra $dname 46 +e ENFORCE Enforces bans on the channel. Any user who is banned will be kicked automatically.
on *:dialog:qbot:sclick:67:did -ra $dname 46 +k KNOWNONLY Any user who joins the channel who is not known (+k) will be kicked. Unless channel mode +i is set they will be banned as well.
on *:dialog:qbot:sclick:66:did -ra $dname 46 +p PROTECT Any user with voice (+v) or operator (+o) access will have that  status enforced on the channel at all times. Same effect as giving all ops and voices the +p chanlev flag.
on *:dialog:qbot:sclick:65:did -ra $dname 46 +v VOICEALL Automatically grants voice (+v) on the channel to any user who enters, unless they have quiet (+q) chanlev flag.
 
on *:dialog:qbot:sclick:26:did -ra $dname 46 To help keep channels clear of the clutter of too many bans, Q can automatically remove channel bans after a specified time
on *:dialog:qbot:sclick:72:did -ra $dname 46 Displays a list of users who have recently been opped on a channel by the service, along with the account name responsible for the opping
on *:dialog:qbot:sclick:73:did -ra $dname 46 Shows some statistics about a channel, including total number of joins and maximum channel size.
on *:dialog:qbot:sclick:74:did -ra $dname 46 Removes all channel modes (such as keys, limits, invite only, etc.)
on *:dialog:qbot:sclick:75:did -ra $dname 46 This shows the current welcome message set on a channel and allows it to be changed. In order to be displayed to users, the feature must be enabled by the +w chanflag
on *:dialog:qbot:sclick:76:did -ra $dname 46 Changes the topic on the channel.
on *:dialog:qbot:sclick:82:did -ra $dname 46 This command resets the named channel if undesired modes, bans or ops have been set. This has the same effect as DEOPALL followed by UNBANALL followed by CLEARCHAN on the channel
on *:dialog:qbot:sclick:81:did -ra $dname 46 Deops every user in the channel. Registered channel operators (+o on CHANLEV) who are protected (via the +p flag in CHANLEV or CHANFLAGS) will not be deopped.
on *:dialog:qbot:sclick:80:did -ra $dname 46 Devoices all users in the channel. Registered voices (+v on CHANLEV) who are protected (+p flag set in CHANLEV or CHANFLAGS) will not be devoiced.
on *:dialog:qbot:sclick:79:did -ra $dname 46 Ops you on one or more channels, or ops other named users on a given channel. This command cannot be used to op users who are otherwise prevented from getting ops.
on *:dialog:qbot:sclick:78:did -ra $dname 46 Grants voice to you on one or more channels, or grants voice to one or more ther users on a particular channel.
on *:dialog:qbot:sclick:22:did -ra $dname 46 Invites you to the named channel
 
on *:dialog:qbot:sclick:8:did -ra $dname 46 +b BANNED Banned from the channel
on *:dialog:qbot:sclick:50:did -ra $dname 46 +a AUTOOP Ops the user automatically when they join the channel (the user must also hold +o in order to have this flag)
on *:dialog:qbot:sclick:87:did -ra $dname 46 +g AUTOVOICE Voices the user automatically when they join the channel (the user must also hold +v in order to have this flag)
on *:dialog:qbot:sclick:51:did -ra $dname 46 +k KNOWN Known on the channel - can get invites to the channel via INVITE
on *:dialog:qbot:sclick:5:did -ra $dname 46 +v VOICE Can get voice on the channel
on *:dialog:qbot:sclick:49:did -ra $dname 46 +o OP Can get ops on the channel
on *:dialog:qbot:sclick:85:did -ra $dname 46 +m MASTER Can add or remove all access except master or owner
on *:dialog:qbot:sclick:48:did -ra $dname 46 +n OWNER Can add or remove masters and all other flags (except personal flags)
on *:dialog:qbot:sclick:102:did -ra $dname 46 +t TOPIC Can use SETTOPIC to alter the topic on the channel
 
on *:dialog:qbot:sclick:94:did -ra $dname 46 +w NOWELCOME Prevents the welcome message being sent when you join the channel.
on *:dialog:qbot:sclick:96:did -ra $dname 46 +j AUTOINV Invites you to the channel automatically when you authenticate.
on *:dialog:qbot:sclick:91:did -ra $dname 46  Changes your register email address. Confirmation of the change will be sent both old and new addresses
on *:dialog:qbot:sclick:90:did -ra $dname 46  Changes your account password. Your new password must be at least 6 characters long, contain at least one number and one letter, and may not contain sequences of letters or numbers.
on *:dialog:qbot:sclick:88:did -ra $dname 46  Authenticates you on the bot.  If you do not have a username and password, type /msg q HELLO <email> <email>
on *:dialog:qbot:sclick:89:did -ra $dname 46  Hides your host (*@AUTHNAME.users.quakenet.org)
 
on *:dialog:qbot:close:0:unset %qbot
menu Nicklist {
  -
  .Q-Commands
  ..Level
  ...+ao:.msg q chanlev # $$1 +ao
  ...-ao:.msg q chanlev # $$1 -ao
  ...+gv:.msg q chanlev # $$1 +gv
  ...-gv:.msg q chanlev # $$1 -gv
  ...+m:.msg q chanlev # $$1 +m
  ...-m:.msg q chanlev # $$1 -m
  .ban
  ..ban:.msg q ban # $$1
  ..delban:.msg q bandel # $$1 $+ *!*@*
  -
}
 
menu Channel {
  -
  Q-Commands
  .Q-Commands:dialog -mod qbot qbot
  .Op:msg q op #
  .Voice:msg q voice #
  .Deopall:msg q deopall #
  .Unbanall:msg q unbanall #
  .Invite:msg q invite #
  .Recover:msg q recover #
  .Set topic:msg q settopic # $?=\"Enter topic:"
  .Auth:msg q@CServe.quakenet.org AUTH $?=\"User Name" $?=\"Pass\"
  .Ban
  ..Ban:msg q ban # $?=\"ban\"
  ..Bandel:msg q bandel $?=\"BanDel\"
  ..Banlist:msg q banlist #
  ..Banclear:.msg q banclear #
}


יש למצוא גם: pastebin.php?mode=view&s=23