מירק סקריפטינג • צפה בנושא

שם הקוד: מידע על ערוץ ביוטיוב
יוצר: intersys
גירסא: 1.1
תיאור: נותן לכם תמידע על הערוץ של המשתמש ביוטיוב
הפעלה: קליק ימני - Youtube Profile Info
תמונה:

הקוד:

קוד: בחר הכל

alias -l youtube { sockclose yti | sockopen yti www.youtube.com 80 | sockmark yti $1 | did -a inf 9 www.youtube.com/user/ $+ $sock(yti).mark $+ /about  }
on *:sockopen:yti: {
  sockwrite -n $sockname GET /user/ $+ $sock(yti).mark $+ /about HTTP/1.0
  sockwrite -n $sockname Host: www.youtube.com
  sockwrite -n $sockname
}
on *:sockread:yti: {
  if (!$sockerr) {
    var %yti | sockread %yti
    if ($regex(%yti,/subscribed" title="(.+?)">/)) { did -a inf 11 $regml(1) }
    elseif ($regex(%yti,/<b>(.+?)</b> views/)) { did -a inf 12 $regml(1) }
    elseif ($regex(%yti,/<meta name="title" content="(.+?)">/)) { did -a inf 10 $regml(1) }
    elseif ($regex(%yti,/Joined(.+)/)) { did -a inf 13 $regml(1) }
    elseif (This channel does not exist isin %yti) { did -a inf 9 הערוץ לא נמצא! }
  }
}

dialog inf {
  title "Youtube Profile"
  size -1 -1 142 80
  option dbu
  box "Youtube Profile Info - By intersys", 1, 2 3 139 75
  text "שם:", 2, 7 16 25 8
  text "מספר משתמשים רשומים:", 3, 7 26 69 8
  text "מספר צפיות בסרטונים:", 4, 7 36 64 8
  text "הצטרף בתאריך:", 5, 7 46 47 8
  edit "", 6, 5 54 50 12
  button "קבל נתונים", 7, 59 54 37 12
  button "סגור", 8, 100 54 37 12
  button "Button", 9, 5 67 133 9
  text "", 10, 94 14 40 8
  text "", 11, 94 24 40 8
  text "", 12, 94 34 40 8
  text "", 13, 94 44 40 8
}
on *:dialog:inf:*:*: {
  if ($devent == init) { 
    did -a $dname 9,10,11,12,13 ריק
  }
  elseif ($devent == sclick) { 
    if ($did == 7) { 
      if ($did(6) == $null) { noop $input(לא רשמת את שם הערוץ,o,שגיאה) }
      if ($did(6) !isalnum) { noop $input(סימנים לא חוקיים בשם הערוץ,o,שגיאה) }
      else { did -a $dname 9,10,11,12,13 ריק | youtube $did(6) }
    }
    elseif ($did == 8) { dialog -x $dname }
    elseif ($did == 9) && (www isin $did(9)) { url www.youtube.com/user/ $+ $sock($sockname).mark $+ /about }
  }
}
menu * {
  Youtube Profile info:{ dialog $iif($dialog(inf),-v,-md) inf inf }
}